TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Avatar de Usuario
explorer
Mensajes: 87
Registrado: 10 Ene 2016 18:43
Ubicación: Valladolid, España
Agradecido : 3 veces
Agradecimiento recibido: 68 veces
Contactar:

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor explorer » 17 Feb 2017 00:23

Último mensaje de la página anterior:

Este es el código, pero como hay una parte con caracteres que solo se ven bien en los Atari, lo vuelvo a adjuntar comprimido, no sea que haya problemas con el copia y pega.

El funcionamiento es, detallado:
  • al principio, salta a la etiqueta start, donde se hacen las operaciones de inicialización e instalación:
  • guardar el valor anterior del byte en $484 (conterm)
  • si existe la jarra de galletas, miramos a ver si ya estábamos instalados de una ejecución anterior. Si es así, salimos.
  • si no estábamos de antes, ponemos una galleta ACT2
  • luego miramos el número de versión de la ROM. Si es menor que 1.2, salimos
  • si es una TOS 1.2 o superior, saltamos a la subrutina conversion
    • en ella, lo primero que hacemos es preguntarle al TOS dónde están las (3) tablas de conversión scan -> ascii
    • luego viene un bucle en que se recorre la información de la tabla (de conversión de caracteres). El proceso que se sigue es:
    • se lee el primer byte, que representa el carácter que hará de "muerta"; y lo buscamos por la tabla de conversión (es decir: estamos buscando qué tecla física es la que tiene dibujado ese carácter). Primero lo buscamos en la tabla unshift (teclado en posición normal) y si no lo encuentra, en la tabla shift (teclado con al menos un shift pulsado) (ahora no recuerdo por qué solo busco por los primeros 60 caracteres de cada tabla)
    • si hemos sido capaces de encontrar la tecla, guardamos ese código de scan en la propia tabla de conversión, en lugar del primer byte leído antes (para reutilizar espacio, claro)
    • en el caso extremo de que no encontremos esa tecla, cabe un último recurso: usar la tecla * como tecla "muerta"
    • todo esto se hace para que el programa de acentos sea completamente independiente del idioma/disposición del teclado
  • una vez terminada la conversión de teclas a códigos scan, preguntamos al TOS dónde está el búfer del teclado, dirección donde se almacena el estado de las teclas shift y la base de los vectores de rutinas del sistema, para instalar nuestra propia rutina "acentos" delante de la que se ejecuta cuando se pulsa una tecla
  • finalmente, salimos del programa, informando al SO que deje residente (en memoria) nuestro programa (mejor dicho: el programa está preparado para dejar residente solo la parte que se necesita)

  • la rutina "acentos" residente hace lo siguiente:
  • primero vemos la posición de la cola del búfer del teclado
  • luego ejecutamos la rutina original del sistema operativo
  • al regresar, comprobamos si el búfer ha cambiado o no
  • si hubo un cambio, y el programa de acentos está activado, vamos al búfer del teclado y vemos qué se ha pulsado
  • si no hubo cambios, podría ser debido a que el usuario pulso las teclas shift, así que comprobamos si está pulsada la combinación Alternate+Shift+Shift, y en ese caso des/activamos el programa
  • si fue la tecla Alternate, salimos de la rutina, pero recordando qué tecla se ha pulsado
  • si es una tecla normal, leemos su código de scan. Si además está pulsada una tecla shift, le sumamos 0x80
  • recorremos la tabla de conversión, buscando por el carácter que se pulso antes que la tecla actual
  • si no lo encontramos, salimos y, otra vez, guardamos esa tecla para después. Todo esto es para detectar la pulsación de las teclas "muertas"
  • si encontramos el scan, es que era una tecla muerta. Ahora tenemos que buscar si el carácter actualmente pulsado está en la lista de conversión
  • si encontramos una coincidencia, sacamos de la tabla el siguiente carácter
  • ahora viene lo curioso: ponemos un Backspace en el búfer del teclado, y a continuación, el nuevo carácter. Esto hace que se emitan esos dos caracteres a la aplicación en la que está el usuario. Esto tiene el efecto visual de borrar el carácter de la tecla muerta y presentar el nuevo carácter (creo que era así, hablo de memoria)
  • finalmente, desactivamos (por si acaso) el modo repetición (es el que ocurre cuando dejamos una tecla pulsada un cierto tiempo)

Como se puede ver, hay algunas cosas que se pueden sacar si solo vamos a manejar un teclado español. La rutina de conversión no es necesaria, porque solo vamos a tener una disposición del teclado (salvo que el usuario SÍ quiera una disposición del teclado distinta).

Y... ahora que veo el código, con 23 años de diferencia... creo que podría dejarlo un poco más óptimo y claro. Al menos, más decente :oops:

Código: Seleccionar todo

*
* Acentos. v1.2
* Joaqu¡n Ferrero.
*
* Versi¢n   Fecha
* v1.0      Agosto 1993
* v1.1      Octubre 1993. Ver si funciona en Tos 1.4. NO VA EN STE!!!
* v1.2      Junio 1994. Quitar shifts para aumentar compatibilidad.
*
* Queda residente, colocando una galleta ACT2
*
   opt   o3+
   opt   ow3+
   opt   o4+
   opt   o5+
   opt   o6+
   opt   e-
   opt   a+

   COMMENT HEAD=7         Todos los atributos

   output   accent.prg

COOKIE   EQU   ACT2

   include "d:devpacatari_st.s"

start1   bra   start

acentos   movem.l d5-d7/a5,-(sp)
   movea.l   buffer_key,a5      Buffer del teclado
   MOVE   8(A5),d6      Posici¢n de cola anterior

   movea.l   anterior_key,A0      Ejecutar anterior rutina
   movem.l   d6/a5,-(sp)      v1.1
   JSR   (A0)
   movem.l   (sp)+,d6/a5      v1.1

   MOVEA.L   kshift,A0      kstate
   MOVE.B   (A0),D0

   move   8(a5),d7      posicion
   cmp   d6,d7         šHubo entrada?
   beq   ver_cambio      No

   TST   activado      šEstamos activados?
   BEQ   no_key         No, acabar

   MOVEA.L   (A5),A0         buffer de teclas
   MOVE.L   0(A0,d7),D6      Leer entrada

   BTST   #3,D0         šSe puls¢ alternate?
   BEQ.S   no_alt

   MOVE.L   D6,D5         Extraer c¢digo scan
   SWAP   D5

   CMPI.B   #$78,D5         L¡mite superior de comparaci¢n
   BCS.S   .ac_1
   SUBI.B   #$76,D5

.ac_1   MOVE.B   D0,D1         kstate
   ANDI.B   #3,D1         šSe puls¢ shift?
   BEQ.S   no_shft
   ORI.B   #$80,D5         scan |= 0x80

no_shft   lea   tabla(pc),A1      Tabla
   move   ant_key,d1      Car cter a buscar

while   move.b   (a1)+,d0
   BEQ.S   no_alt         šFin de tabla?

   CMP.B   D5,d0         šEs el car cter que buscamos?
   BEQ.S   si_char

.lp   tst.b   (a1)+         buscar fin de cadena
   BNE.S   .lp
   BRA.S   while         seguir con otra cadena

si_no   ADDQ.W   #1,A1
si_char   move.b   (a1)+,d0      Car cter entrado posiblemente
   BEQ.S   no_alt         no encontrado, acabar
   CMP.B   d1,D0         šEs el mismo que el entrado?
   BNE.S   si_no         no, seguir buscando

   MOVE.B   (A1),D6         Nuevo car cter
   BCLR   #$1B,D6         Quitar alternate
   BCLR   #$18,D6         Quitar shifts (v1.2)
   BCLR   #$19,D6

   move.l   #$E0008,0(a0,d7)   Poner Backspace
   ADDQ.W   #4,D7         Siguiente posici¢n
   CMP.W   4(A5),D7      šLlegamos al final?
   BLT.S   no_lim
   MOVEQ   #0,D7         Empezar buffer de nuevo
no_lim   cmp   6(A5),d7      šLlegamos a la cabeza?
   BEQ.S   no_alt
   MOVE.W   D7,8(A5)      Nueva cola
   MOVE.L   D6,0(A0,D7)      Nueva entrada
   MOVE.B   $484.w,ant_484      Salvar estado del 484
   BCLR   #1,$484.w      Quitar modo repetici¢n

no_alt   MOVE   D6,ant_key      Guardar c¢digo ascii
no_key   movem.l (sp)+,d5-d7/a5
   rts

ver_cambio:
   MOVE.B   ant_484,D1      Recuperar estado de repetici¢n
   ANDI.B   #2,D1
   OR.B   D1,$484.w
   CMP.B   #$B,D0         Se puls¢ Alt+shift+shift
   BNE.S   no_key
   not   activado
   bra.s   no_key

tabla
   dc.b   ",C?c?",0
   dc.b   ".Aa?.úøù",0
   dc.b   "^a?e?i?o?u?",0
   dc.b   "`A¶a?e?io?u?",0
   dc.b   "_+ñ<ó=ð>òaŠo§",0
   dc.b   " ºEa e?i¡o¢u£",0
   dc.b   "~A·N¥Oža°n€o±=÷iß",0
   dc.b   "/O²PŒc?o³3á2«4¬Sì",0
   dc.b   "-:öL?Y<©>ªA?Oµa?oŽ",0
   dc.b   ": ¹A?O?U?a?e?i?o?uy?",0
   dc.b   8,"!­?š<®>¯{ô}õiÀIÁcœC»RûrŸT¿nü2ý3þ_ÿ"
   dc.b   "aàbáGâdëDzékÂlÄmæxèXîpãPïsåSätçfíF?oêA¶",0
   dc.b   "*                      ",0,0
   even
ant_484   DC.B   0
ant_key   dc.w   0
activado:
   DC.W   -1         Inicialmente activado
   even
kshift   DC.L   0
buffer_key:
   DC.L   0
anterior_key
   DC.L   0
   DC.B   "____"
   DC.B   "JF94"
   DC.B   "2006"
   DC.L   -1
   DC.L   0
fin_acentos:

start   move.l   4(sp),a5      Basepage
   LEA   $100-32(A5),A7      Poner pila al fin l de comandos

   Super
   MOVEA.L   $4F2.W,A6      Inicio del S.O.
   MOVE.B   $484.W,ant_484      Iniciar valores
   moveq   #0,d7         Flag de instalaci¢n
   move.l   _p_cookies.w,d0      Jarra de galletas
   beq.s   no_jar
   movea.l   d0,a0
.loop_g   movem.l   (a0)+,d0-d1      Leer galletas
   tst.l   d0
   beq.s   poner         Se encontr¢ el final, poner nueva
   cmp.l   #COOKIE,d0      šEst  ya puesto?
   bne.s   .loop_g         No, seguir buscando
   bra.s   ya_pues
poner   subq.l   #8,a0         Volver atr s un momento
   move.l   #COOKIE,(a0)+      Identificador
   move.l   a5,(a0)+      Poner basepage
   movem.l   d0-d1,(a0)      Recuperar anterior galleta
no_jar   moveq   #1,d7         S¡ se instal¢
ya_pues   User
   tst   d7         šSe instal¢?
   beq.s   acabar         No

   MOVEA.L   8(A6),A6      Verdadero inicio del s.o.
   CMPI.W   #$102,2(A6)      Testear n£mero de versi¢n
   BCC.S   si_tos         Es igual o mayor
acabar   Cconws_p txt_no_instal(pc)
   Pterm0            Salir inmediatamente

si_tos   bsr.s   conversion      Conversi¢n de las tablas
   MOVE.L   $24(A6),kshift      Direcci¢n de shifts state

   Iorec   #1         Hallar buffer del teclado
   MOVE.L   D0,buffer_key

   Kbdvbase         Base de vectores rutinas del sistema
   MOVEA.L   D0,A5
   MOVE.L   $20(A5),anterior_key   Anterior rutina del sistema

.lp   TAS   $24(A5)         Esperar fin de transmisi¢n
   BNE.S   .lp

   LEA   acentos(PC),A0      Instalar rutina propia
   MOVE.L   A0,$20(A5)
   clr.b   $24(a5)

   Cconws_p txt_si_instal(pc)   S¡ se instal¢
   Ptermres #fin_acentos+$100-acentos,#0   Quedar residente

conversion:
   MOVEQ   #-1,D0
   Keytbl   d0,d0,d0      Hallar tablas de conversi¢n scan->ascii

   lea   tabla(pc),A2      Inicio de tabla
   MOVEA.L   D0,A0         Inicio de apuntadores
   MOVE.B   (A2),D2         Primer car cter a convertir
loop_c   MOVEA.L   (A0),A1         Apuntador a tabla unshift
   CLR.W   D3         Contador
   BSR.S   Buscar
   BPL.S   si_conv
   MOVE.W   #$80,D3         Probar con la tabla shift
   MOVEA.L   4(A0),A1
   BSR.S   Buscar
   BPL.S   si_conv
   BSR.S   Arreglo         No, hacer chapuza con el car cter *
   MOVE.B   #$FF,D3         Desconectar esa cadena

si_conv   MOVE.B   D3,(A2)         El nuevo car cter (scan)

.loop1   TST.B   (A2)+         Buscar final de cadena
   BNE.S   .loop1

   MOVE.B   (A2),D2         Siguiente car cter
   BNE.S   loop_c
   RTS

Buscar   MOVEQ   #$3C,D1         N£mero m ximo de intentos de b£squeda
.lp_b   ADDQ.W   #1,D3
   CMP.B   (A1)+,D2
   DBEQ   D1,.lp_b
   SUBQ.W   #1,D3
   TST.W   D1
   RTS

Arreglo   MOVE.L   A2,-(A7)      Copiar cadena a cadena *
   lea   tabla(pc),A1      Inicio de tabla

.lp_a   CMPI.B   #*,(A1)+      Buscar *
   BNE.S   .lp_a

   ADDQ.L   #1,A2
.lp_a1   MOVE.B   (A2)+,(A1)+      Copiar el resto de la cadena
   BNE.S   .lp_a1
   CLR.B   (A1)         Poner segundo 0, indicador final tabla
   MOVEA.L   (A7)+,A2
   RTS

   data

txt_no_instal:
   dc.b   CR,LF,"Acentos v1.2 no instalado",CR,LF,0
txt_si_instal:
   dc.b   CR,LF,"Acentos v1.2 instalado."
   dc.b   CR,LF,"Joaqu¡n Ferrero. Junio 1994",CR,LF,0

   end
Adjuntos
accent.s.zip
v1.2 código fuente del programa de acentos
(2.88 KiB) Descargado 15 veces

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 17 Feb 2017 07:16

Gracias por el programa!
La ROM tiene bastante sitio. Por lo es factible incorporar el programa. O eso creo.
Otra cosa diferente es que sepa hacerlo.
No encuentro un desensamblador que me ayude en la tarea.
Y de Mundo Atari me pillas un poco despistado.
Pero el tema es intentarlo. :D

Avatar de Usuario
explorer
Mensajes: 87
Registrado: 10 Ene 2016 18:43
Ubicación: Valladolid, España
Agradecido : 3 veces
Agradecimiento recibido: 68 veces
Contactar:

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor explorer » 17 Feb 2017 10:15

Pues si hay sitio en la ROM se puede hacer: solo se necesita apenas 1 KB. Y para dejarlo bien, consistiría en modificar la llamada del vector original de procesamiento del teclado.

Pero... ¿realmente merece la pena todo esto comparado con ejecutar un programa más en la carpeta AUTO y perder 1 KB de la RAM?

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 17 Feb 2017 10:57

explorer escribió:Pues si hay sitio en la ROM se puede hacer: solo se necesita apenas 1 KB. Y para dejarlo bien, consistiría en modificar la llamada del vector original de procesamiento del teclado.

Pero... ¿realmente merece la pena todo esto comparado con ejecutar un programa más en la carpeta AUTO y perder 1 KB de la RAM?


Bueno, la TOS en español era un tema missing.
Me animé a traducirla por aportar algo a la comunidad, a parte de chistes malos sobre el Amiga.
Lo del mapeo del teclado fue una cosa que me di cuenta cuando estaba en el ajo. No tenía conocimiento de tu parche hasta que no lo comentaste (por desconocimiento mío de todo lo relacionado con el Atari)

No sé hasta que punto puede merecer la pena incorporar el parche dentro de la ROM. Pero lo que está claro es que me puedo entretener a la par de aprender.

Aunque no lo consiga (o no tenga sentido incorporarlo)... mientras lo intente y aprenda cosas, entonces sí merecerá la pena.

Y mientras tanto, tenemos tu parche!!! -thumbup

Avatar de Usuario
Chema
Mensajes: 1530
Registrado: 21 Jun 2012 20:13
Ubicación: Gijón
Agradecido : 433 veces
Agradecimiento recibido: 186 veces
Contactar:

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor Chema » 17 Feb 2017 11:12

minter, como no dejes la mayoría de los detalles cachondos es pa matarte :) Ya puestos a hacer algo así, que se note la mano del autor, siempre que no moleste XD

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 17 Feb 2017 12:17

Chema escribió:minter, como no dejes la mayoría de los detalles cachondos es pa matarte :) Ya puestos a hacer algo así, que se note la mano del autor, siempre que no moleste XD


Tengo a diablín escondido en la ROM. -507
Y RW está a la vista.

Por cierto, estoy haciendo pruebas con el programa accent... incorporado en la ROM, y me hace cosas raras.

¿Como debería de funcionar correctamente?
Pulso pero no me devuelve al modo normal... luego se me queda pegado el Alternate...

Bueno, primera prueba al palo! -banghead
Ahora... a trabajar... -507
Cosas rares.jpg
Cosas rares
Cosas rares.jpg (63.56 KiB) Visto 726 veces


Ah! no os fijéis en el programa que tengo abierto. Es que es en francés. No es tema de la TOS

Avatar de Usuario
explorer
Mensajes: 87
Registrado: 10 Ene 2016 18:43
Ubicación: Valladolid, España
Agradecido : 3 veces
Agradecimiento recibido: 68 veces
Contactar:

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor explorer » 17 Feb 2017 19:54

El funcionamiento normal (cuando se le ejecuta desde el escritorio o desde AUTO/) debería ser casi el mismo que cuando usamos Windows, Linux o Mac: primero pulsamos la "tecla muerta" y vemos en pantalla su carácter, por ejemplo, un acento diacrítico:

A continuación pulsamos una tecla que pueda combinar con la tecla anterior (consultar la documentación que acompaña al programa). Si, por ejemplo, pulsa la a, debería entonces emitirse dos caracteres: un retroceso (backspace) que borre el acento anterior, y el nuevo carácter. Entonces queda solo
á

Si se queda pegado el Alternate... es muy posible que la parte del código que quita el modo repetición de teclas no está funcionando bien. O quizás la v3.06 trae los suficientes cambios como para que no sea compatible. Sí que lo probé con un v3.05 en un TT030 de un amigo (de hecho, todo el mundo que conocía que tenía Atari, en aquella época, usaba mi programa a diario, en lugar del que venía con el sistema).

Interesante... en el archivo TT030.zip referenciado por ron en viewtopic.php?f=39&t=887#p11499 veo que hay un archivo llamado keyboard.u1. No sé lo que es.

Avatar de Usuario
ron
Mensajes: 17172
Registrado: 28 Oct 2010 14:20
Ubicación: retrocrypta
Agradecido : 508 veces
Agradecimiento recibido: 528 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor ron » 18 Feb 2017 13:23

keyboard.u1 pesa 4KB y es una ROM. El Mega ST también tiene esta ROM.

ROM_REGION( 0x1000, HD6301V1_TAG, 0 )
ROM_LOAD( "keyboard.u1", 0x0000, 0x1000, CRC(xxxxxx)

==== Keyboard Interface ====

The TT keyboard interface is a compatible superset of the one found on the ST/MEGA computers. The keyboard is equipped with a combination mouse/joystick port and a joystick only port. The keyboard transmits encoded make/break key scan codes (with two key rollover), mouse/trackball data, joystick data, and time-of-day. The keyboard receives commands and sends data via bidirectional communication implemented with a MC6850 Asynchronous Communications Interface Adapter (ACIA). The data transfer rate is 7812.5 bits/second. All keyboard functions, such as key scanning, mouse tracking, command parsing, etc. are performed by a HD6301V1 8-bit microcomputer unit. (See the Atari Intelligent Keyboard (ikbd) Protocol. February 26, 1985.)

Avatar de Usuario
VikTOS
Mensajes: 110
Registrado: 28 Jul 2016 08:27
Agradecido : 10 veces
Agradecimiento recibido: 13 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor VikTOS » 19 Feb 2017 19:37

Estrayk escribió:
minter escribió:
Atari TOS306 opciones.jpg


Pon "Blitter" en vez de "Cache".


Añadir que el TT no tiene Blitter..... pero si, lo correcto es Blitter no Cache.

Gracias por el trabajo y por el aporte. Si alguien graba estas ROM, por fi, que lo diga, que estoy interesado en unas.

SaluTOS
-j4tar1 -heart -coam1
-bRick

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 19 Feb 2017 20:38

vhenares escribió:Gracias por el trabajo y por el aporte. Si alguien graba estas ROM, por fi, que lo diga, que estoy interesado en unas.

SaluTOS

No hay de que! -thumbup
En todo caso, antes de grabar, probaría un poco con los emus. Creo que tengo algún texto que ha quedado mal justificado y se cortan o repiten palabras.
Voy a ir corrigiendo, pero si veis algo, me lo comentáis.
Para el próximo viernes, a ver si subo una casi definitiva. Mañana y pasado estaré muy ocupado, pero luego tendré unos días para corregir esos fallos.

Avatar de Usuario
eldelcairo
Mensajes: 533
Registrado: 06 May 2015 17:32
Ubicación: Andorra la Vella
Agradecido : 463 veces
Agradecimiento recibido: 73 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor eldelcairo » 22 Feb 2017 16:41

minter escribió:No hay de que! -thumbup
En todo caso, antes de grabar, probaría un poco con los emus. Creo que tengo algún texto que ha quedado mal justificado y se cortan o repiten palabras.
Voy a ir corrigiendo, pero si veis algo, me lo comentáis.
Para el próximo viernes, a ver si subo una casi definitiva. Mañana y pasado estaré muy ocupado, pero luego tendré unos días para corregir esos fallos.


Hola minter!

Probando, probando... Hemos encontrado algunos textos que, si se pueden cambiar sería genial, serían más fieles a lo que suelen ser los textos de Tos/GEM en los Atari. No sé la dificultad que contrae hacer estas modificaciones, o sea que tu valoras y decides, que eres el que se lo curra…

Te mando un mensaje privado, que no parezca lo que no es, que vayamos de sobradetis, con rentintín o algo por el estilo XD -drinks
.
Grupo Comunidad -j4tar1 en TelegramAquí
https://t.me/joinchat/AETBTw7LlSjZJk2dMZK1pg
Preservación de documentación, software y archivos relacionados con los ordenadores Atari
https://t.me/comunidad_atari_aportes

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 22 Feb 2017 17:08

Para nada me parece mal que me indiques los fallos.
Eso era lo que pedía, que probarais y me fuerais indicando. -thumbup

No pasa nada por que me envíes un correo privado.
Voy a poner parte del texto del correo para tener un control de cambios en el post:

Querido Minter.
La última ocasión que coincidimos, tu presencia me embriagó. Tus finas manos tecleando mi ordenador...


Ostia! Este correo no!!!
El otro!!!
-507 -507 -507


Comenzamos, algunos son un poco chominadas, los enumero por orden de aparición:

- Menú Desk: Información faltaría la tilde en la "o".

- Cuando haces doble clic en el icono de las Unidades de Disco sin disquete insertado, en el cuadro de aviso:
A) El texto del cuadro de diálogo, cambiar el infinitivo "Verificar" por la segunda persona "Verifica"
B) en el mismo texto del cuadro de diálogo, deberían haber dos botones: ABANDONAR y REINTENTAR, pero ambas opciones se han unido en un solo botón.


- Menú Fichero:
A) Abrir una aplicación le falta tilde en la "o".
B) Los dos botones de acción estaría bien que estuviesen en el mismo tiempo verbal, es decir, "Confirmar" y "Anular" o "Confirma" y "Anula".

- Menú Ver:
A) Comparándolo con otros TOS, las opciones suelen ser "Ver como icono", "Ver como texto" y "Ningún orden" sin poner mayúscula en "orden".
B) En Definir estilo y colores, "Para Escrit" cambiar por " Para Texto".

- Menú Opciones:
A) Instalar un periférico le falta tilde en la "e"
B) "Definir LAS preferencias" sin el artículo "LAS".
C) En su mismo cuadro de diálogo, debería aparecer "DEFINIR PREFERENCIAS".
D) Hay que sustituir la frase "Se requiere confirmación" por "Pedir confirmación para".
E) Las opciones son "Borrar", "Copiar" y "Remplazar".
F) Resolución de pantalla le falta tilde en la "o".
G) Las opciones deben ser "ST BAJA", "ST MEDIA", "TT BAJA" y "TT MEDIA", las demás están bien.
H) “Leer un Fichero .INF” sin el punto antes de INF
I) "Configuración escritorio" por "Configurar escritorio". Dentro de éste cuadro de diálogo faltan las tildes en "Aplicación", "función", "pulsación" y "Función", esta última dos veces.


Ok! Voy a ponerme manos a la obra. -thumbup

Avatar de Usuario
eldelcairo
Mensajes: 533
Registrado: 06 May 2015 17:32
Ubicación: Andorra la Vella
Agradecido : 463 veces
Agradecimiento recibido: 73 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor eldelcairo » 22 Feb 2017 17:38

minter escribió:
... E) Las opciones son "Borrar", "Copiar" y "Remplazar". ...


"Reemplazar" con doble E

[Aunque el Diccionario de la lengua española recoge ambos términos, la Academia recomienda el uso de la segunda, es decir, escrita con doble e, reemplazar]
.
Grupo Comunidad -j4tar1 en TelegramAquí
https://t.me/joinchat/AETBTw7LlSjZJk2dMZK1pg
Preservación de documentación, software y archivos relacionados con los ordenadores Atari
https://t.me/comunidad_atari_aportes

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 24 Feb 2017 16:30

Buenas eldelcairo,


Comenzamos, algunos son un poco chominadas, los enumero por orden de aparición:

- Menú Desk: Información faltaría la tilde en la "o". -Ok

- Cuando haces doble clic en el icono de las Unidades de Disco sin disquete insertado, en el cuadro de aviso:
A) El texto del cuadro de diálogo, cambiar el infinitivo "Verificar" por la segunda persona "Verifica" Ok
B) en el mismo texto del cuadro de diálogo, deberían haber dos botones: ABANDONAR y REINTENTAR, pero ambas opciones se han unido en un solo botón.Ok


- Menú Fichero:
A) Abrir una aplicación le falta tilde en la "o".
B) Los dos botones de acción estaría bien que estuviesen en el mismo tiempo verbal, es decir, "Confirmar" y "Anular" o "Confirma" y "Anula". Ok

- Menú Ver:
A) Comparándolo con otros TOS, las opciones suelen ser "Ver como icono", "Ver como texto" y "Ningún orden" sin poner mayúscula en "orden".Ok
B) En Definir estilo y colores, "Para Escrit" cambiar por " Para Texto". Cambiado a Fondo.

- Menú Opciones:
A) Instalar un periférico le falta tilde en la "e" Ok
B) "Definir LAS preferencias" sin el artículo "LAS". Ok
C) En su mismo cuadro de diálogo, debería aparecer "DEFINIR PREFERENCIAS". Ok
D) Hay que sustituir la frase "Se requiere confirmación" por "Pedir confirmación para". Ok
E) Las opciones son "Borrar", "Copiar" y "Remplazar". Ok
F) Resolución de pantalla le falta tilde en la "o". Ok
G) Las opciones deben ser "ST BAJA", "ST MEDIA", "TT BAJA" y "TT MEDIA", las demás están bien. Ok
H) “Leer un Fichero .INF” sin el punto antes de INF Ok
I) "Configuración escritorio" por "Configurar escritorio". Dentro de éste cuadro de diálogo faltan las tildes en "Aplicación", "función", "pulsación" y "Función", esta última dos veces. Ok


Bueno, ya va cogiendo mejor pinta. Me está gustando hasta a mí. -507
El punto A, al ser mayúsculas toda la cadena, no puedo poner tilde.
No están las tildes en mayúsculas con tilde cargadas en la ROM. Es decir, no puedo! -no

Subo la segunda beta retrowikera! -thumbup
Adjuntos
TOS306esBeta2RW.rar
TOS306es_beta2RW
(127.71 KiB) Descargado 18 veces

Avatar de Usuario
eldelcairo
Mensajes: 533
Registrado: 06 May 2015 17:32
Ubicación: Andorra la Vella
Agradecido : 463 veces
Agradecimiento recibido: 73 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor eldelcairo » 01 Mar 2017 08:01

Buenas! Hemos encontrado ésto:

http://dev-docs.atariforge.org/files/tos306de.tar.bz2

Es el código de fuente de Atari Tos de las versiones 2.06, 2.08 y 3.06.
.
Grupo Comunidad -j4tar1 en TelegramAquí
https://t.me/joinchat/AETBTw7LlSjZJk2dMZK1pg
Preservación de documentación, software y archivos relacionados con los ordenadores Atari
https://t.me/comunidad_atari_aportes

Avatar de Usuario
eldelcairo
Mensajes: 533
Registrado: 06 May 2015 17:32
Ubicación: Andorra la Vella
Agradecido : 463 veces
Agradecimiento recibido: 73 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor eldelcairo » 01 Mar 2017 13:06

- Menú Desk: "Información" tilde en la "ó".

- Menú Fichero:
- ABRIR UNA APLICACIÓN" tilde en la "ó".

- Buscar: "BÚSQUEDA D FICHERO" tilde en la "Ú" y falta la "E" en "DE FICHERO". Puede corregirse o dejar simplemente "BUSCAR FICHERO".

- Cuando se indica un nombre de fichero, por ejemplo XXXX, para buscarlo y no se encuentra, sale el mensaje de error "XXXX no encontra"; se podría sustituir por "no aparece".

- Suprimir: "¿Deseas borrar los archivos o eliminar los iconos?": falta la interrogación de inicio y está la opción de substituirla por la palabra "eliminar" o por "borrar", para que coincida con los botones que aparecen.

Telita con la cantidad de palabras y locuciones a traducir!! gracias por tu trabajo totalmente altruista.
Grupo Comunidad -j4tar1 en TelegramAquí
https://t.me/joinchat/AETBTw7LlSjZJk2dMZK1pg
Preservación de documentación, software y archivos relacionados con los ordenadores Atari
https://t.me/comunidad_atari_aportes

Avatar de Usuario
minter
Mensajes: 1338
Registrado: 22 Jul 2014 18:51
Agradecido : 568 veces
Agradecimiento recibido: 283 veces

Re: TOS 3.05 Spanish Se busca para preservar (THE WANTED)

Mensajepor minter » 01 Mar 2017 21:03

No te lo vas a creer, pero existe la TOS 306 en español. Y tú la acabas de encontrar!!! -banghead

Mira el archivo config.mak

Y verás esto:

# Country definition
# valid countries are:
# us - USA
# de - Germany
# fr - France
# uk - United Kingdom
# es - Spain
# it - Italy
# sv - Sweden
# sf - Switzerland (French)
# sg - Switzerland (German)
#
# sf and sg only affect the country code in ROM header
# uk uses uk keyboard, and us resources
# sg uses de keyboard and resources
# sf uses fr keyboard and resources
#
COUNTRY=de


Si compilamos el fuente, cambiando de por es... se supone que ya lo tenemos.

¿Y los textos?

Pues mira lo que me he encontrado: -shock

Código: Seleccionar todo

Nconflict[] = "­NOMBRE CONFLICTIVO!";
char const Rname[] = "RENOMBRAR ITEM DESTINO";
char const Crenstr[] = "COPIAR Y RENOMBRAR ITEM(S)";
char const Mrenstr[] = "MOVER Y RENOMBRAR ITEM(S)";
char const Istr[] = " %L bytes usados en %W item.";
char const Isels[] = " %L bytes usados en %W items seleccionados.";
char const Isel[] = " %L bytes usados en %W item seleccionado.";
char const Istrs[] = " %L bytes usados en %W items.";
char const Device[] = "DISPOSITIVO";
char const Sinf[] = "Seleccione un Fichero INF";
char const Litem[] = "Ubicar item.";


Todos los archivos punto lo que sea que acaban en es (como por ejemplo: deskes.h , stres.h ... lo que sea acabado en es.archivo)

Están en español!!!! -shock

El trabajo ya estaba hecho!!! -banghead

Jajaja!!! Que bueno!!!! Que gañanes somos!!!! -507
Solo hay que compilarlo!!!! -nb

Bueno... el curro ya está hecho! jajajaja!!! Arreglaré estas cosas que me comentas y mas adelante, intentamos compilar las TOS306 oficial en español!!!

Y tendremos la que más nos gusta, la Retrowikera o la oficial (que por cierto... podrás cambiarle cositas)

Igual en este punto, nos puede ayudar explorer a compilarlo si recuerda como lo hizo tiempo ha sus programas o nos orienta.

Que subidon!!! -thumbup

No se si se puede compilar desde MiNT. -nb Ahí ya me pilláis.


Volver a “Software ST”

¿Quién está conectado?

Usuarios navegando por este Foro: No hay usuarios registrados visitando el Foro y 2 invitados